ModuleConfig.cfc

component {

	this.name         = "quick";
	this.author       = "Eric Peterson";
	this.webUrl       = "https://github.com/coldbox-modules/quick";
	this.dependencies = [ "qb", "str", "mementifier" ];
	this.cfmapping    = "quick";

	function configure() {
		settings = {
			"defaultGrammar"                 : "AutoDiscover@qb",
			"defaultQueryOptions"            : {},
			"parallelEagerLoading"           : false,
			"parallelEagerLoadingExecutor"   : "",
			"parallelEagerLoadingMaxThreads" : 4,
			"parallelEagerLoadingTimeout"    : 60000,
			"preventDuplicateJoins"          : true,
			"preventLazyLoading"             : false,
			"automaticTimestamps"            : true,
			"refreshOnSaveFallback"          : true,
			"lazyLoadingViolationCallback"   : ( entity, relationName ) => {
				throw(
					type    = "QuickLazyLoadingException",
					message = "Attempted to lazy load the [#arguments.relationName#] relationship on the entity [#arguments.entity.mappingName()#] but lazy loading is disabled. This is usually caused by the N+1 problem and is a sign that you are missing an eager load."
				);
			},
			"metadataCache" : {
				"name"       : "quickMeta",
				"provider"   : "coldbox.system.cache.providers.CacheBoxColdBoxProvider",
				"properties" : {
					"objectDefaultTimeout"  : 0, // no timeout
					"useLastAccessTimeouts" : false, // no last access timeout
					"maxObjects"            : 300,
					"objectStore"           : "ConcurrentStore"
				}
			}
		};

		interceptorSettings = {
			customInterceptionPoints : [
				"quickInstanceReady",
				"quickPreLoad",
				"quickPostLoad",
				"quickPostReplicate",
				"quickPreSave",
				"quickPostSave",
				"quickPreInsert",
				"quickPostInsert",
				"quickPreUpdate",
				"quickPostUpdate",
				"quickPreDelete",
				"quickPostDelete",
				"quickRelationshipLoaded"
			]
		};

		binder.map( "quick.models.BaseEntity" ).to( "#moduleMapping#.models.BaseEntity" );
		binder
			.map( "EntityDefinitionRegistry@quick" )
			.to( "#moduleMapping#.models.EntityDefinitionRegistry" )
			.asSingleton();

		binder.getInjector().registerDSL( "quickService", "#moduleMapping#.dsl.QuickServiceDSL" );
	}

	function onLoad() {
		variables.ownsParallelEagerLoadExecutor = false;
		if ( settings.parallelEagerLoading ) {
			configureParallelEagerLoading();
		}

		binder
			.map( alias = "QuickQB@quick", force = true )
			.to( "#moduleMapping#.models.QuickQB" )
			.initArg( name = "grammar", dsl = settings.defaultGrammar )
			.initArg( name = "preventDuplicateJoins", value = settings.preventDuplicateJoins )
			.initArg( name = "defaultOptions", value = settings.defaultQueryOptions )
			.initArg( name = "utils", dsl = "QueryUtils@qb" )
			.initArg( name = "returnFormatterRegistry", ref = "ReturnFormatterRegistry@qb" )
			.initArg(
				name = "validateDuplicateSelectColumns",
				dsl  = "coldbox:moduleSettings:qb:validateDuplicateSelectColumns"
			)
			.initArg(
				name = "validateQueryExecuteReturnType",
				dsl  = "coldbox:moduleSettings:qb:validateQueryExecuteReturnType"
			)
			.initArg( name = "collectQueryLog", dsl = "coldbox:moduleSettings:qb:collectQueryLog" )
			.initArg( name = "sqlCommenter", ref = "ColdBoxSQLCommenter@qb" )
			.initArg( name = "returnFormat", value = "array" );

		if ( isSimpleValue( settings.metadataCache ) ) {
			settings.metadataCache = { "name" : settings.metadataCache };
		}

		if ( settings.metadataCache.name != "quickMeta" ) {
			binder.map( "cachebox:quickMeta" ).toDSL( "cachebox:#settings.metadataCache.name#" );
		} else {
			wirebox.getCachebox().createCache( argumentCollection = settings.metadataCache );
		}
	}

	private void function configureParallelEagerLoading() {
		var asyncManager = wirebox.getInstance( "AsyncManager@coldbox" );
		if ( trim( settings.parallelEagerLoadingExecutor ) == "" ) {
			settings.parallelEagerLoadingExecutor = "quick-parallel-eager-loading";
			if ( !asyncManager.hasExecutor( settings.parallelEagerLoadingExecutor ) ) {
				asyncManager.newExecutor(
					name           = "quick-parallel-eager-loading",
					type           = "fixed",
					threads        = max( 1, int( settings.parallelEagerLoadingMaxThreads ) ),
					loadAppContext = true
				);
				variables.ownsParallelEagerLoadExecutor = true;
			}
		} else if ( !asyncManager.hasExecutor( settings.parallelEagerLoadingExecutor ) ) {
			throw(
				type    = "QuickParallelEagerLoadingExecutorNotFound",
				message = "The configured parallel eager-loading executor [#settings.parallelEagerLoadingExecutor#] is not registered with ColdBox's AsyncManager."
			);
		}

		var parallelExecutorMaxThreads = asyncManager
			.getExecutor( settings.parallelEagerLoadingExecutor )
			.getMaximumPoolSize();
		if ( parallelExecutorMaxThreads <= 0 || parallelExecutorMaxThreads >= 2147483647 ) {
			throw(
				type    = "QuickParallelEagerLoadingExecutorNotBounded",
				message = "The configured parallel eager-loading executor [#settings.parallelEagerLoadingExecutor#] must have a bounded maximum pool size."
			);
		}
	}

	function onUnload() {
		if ( wirebox.containsInstance( "EntityDefinitionRegistry@quick" ) ) {
			wirebox.getInstance( "EntityDefinitionRegistry@quick" ).clear();
		}
		if ( variables.ownsParallelEagerLoadExecutor ) {
			var asyncManager = wirebox.getInstance( "AsyncManager@coldbox" );
			if ( asyncManager.hasExecutor( settings.parallelEagerLoadingExecutor ) ) {
				asyncManager.deleteExecutor( settings.parallelEagerLoadingExecutor );
			}
		}

		var cacheBox = wirebox.getCachebox();
		if ( cacheBox.cacheExists( settings.metadataCache.name ) ) {
			cacheBox.getCache( settings.metadataCache.name ).clearAll();
		}
	}


	/**
	 * This interceptor ensures that the `_mapping` property for a Quick entity
	 * is correctly set to the mapping used in WireBox.
	 *
	 * @event          The current request context
	 * @interceptData  The intercept data for `afterInstanceAutowire`.
	 *                 { mapping, target, targetID, injector }
	 */
	function beforeInstanceAutowire( event, interceptData ) {
		if ( structKeyExists( interceptData.target, "isQuickEntity" ) ) {
			interceptData.target.set_mapping( interceptData.targetID );
		}
	}

}